<!--#include file="masterinclude.asp"-->
<!--#include file="session.asp"-->
<!--#include file="color.asp"-->
<!--#include file="js/right_functions.asp"-->
<!--#include file="js/calClass.asp"-->
<!--#include file="language.asp"-->
<% 
Dim deletefile:deletefile = CheckDelimitedFormat(request.queryString("deletefile"),"|")
Dim appid:appid = request.queryString("appid")
Dim memori:memori = request.queryString("memori")
Dim allforum, forumid, strSQL, objRS, UpRestriction, temparr, isUploadAllowed, memAllowSigpic, PMUpload, mode,profileUpload,avatarUpload
Dim calendarID:calendarID = request.querystring("calendarID")
isUploadAllowed = true
mode = request.queryString("mode")
Dim maxnumupload:maxnumupload = iff(len(""&request.querystring("maxnumupload")),request.querystring("maxnumupload"),1)
Dim i
'response.write maxnumupload

SELECT Case mode
Case "cal"
	Dim objCalendar
	Set objCalendar = new calClass
		With objCalendar
			.calendarID = calendarID
			.mem = memID
			.getPermission
			UpLoadSizeLimit = .uploadSize
			uploadformat = .uploadFormat
		end with
	Set objCalendar = nothing
	if UploadSizeLimit = "0" or len(UploadSizeLimit) = 0 then isUploadAllowed = false
	if len(uploadformat) = 0 then isUploadAllowed = false
Case "sig"
	set objRS = server.createobject("adodb.recordset")
		With objRS
			.open "SELECT allowSigpicture FROM pgd_members WHERE mem="&Clng(memID), datastore, , , adCmdText
				memAllowSigpic = objRS(0)
			.close
		End With
	set objRS = nothing
	if Application(dbName&"allowsigupload") = 0 or memAllowSigpic = 0 then 	response.end
	set objRS = server.createobject("adodb.recordset")
    	With objRS
    		.open "SELECT avatarUpload FROM pgd_Config", datastore, , , adCmdText
    			avatarUpload  = split(objRS(0),"|")
    		.close
    	End With
    set objRS = nothing
	UpLoadSizeLimit = avatarUpload(0)
	uploadformat = avatarUpload(1)
	if UploadSizeLimit = "0" or len(UploadSizeLimit) = 0 then isUploadAllowed = false
	if len(uploadformat) = 0 then isUploadAllowed = false		
	
Case "PM"
	set objRS = server.createobject("adodb.recordset")
    	With objRS
    		.open "SELECT PMUpload FROM pgd_Config", datastore, , , adCmdText
    			PMUpload  = split(objRS(0),"|")
    		.close
    	End With
    set objRS = nothing
	UpLoadSizeLimit = PMUpload(0)
	uploadformat = PMUpload(1)
	if UploadSizeLimit = "0" or len(UploadSizeLimit) = 0 then isUploadAllowed = false
	if len(uploadformat) = 0 then isUploadAllowed = false
	
Case "prof"
	if Application(dbName&"allowProfPhoto") < 2 then response.end
	set objRS = server.createobject("adodb.recordset")
    	With objRS
    		.open "SELECT profileUpload FROM pgd_Config", datastore, , , adCmdText
    			profileUpload  = split(objRS(0),"|")
    		.close
    	End With
    set objRS = nothing
	UpLoadSizeLimit = profileUpload(0)
	uploadformat = profileUpload(1)
	if UploadSizeLimit = "0" or len(UploadSizeLimit) = 0 then isUploadAllowed = false
	if len(uploadformat) = 0 then isUploadAllowed = false	
	
Case Else
	'if	mode = "edit" then
		Dim existingUpfileCount:existingUpfileCount = ubound(split(deletefile,"|"))+1
	'end if
	
	allforum = Application(dbName&"foruminfo")
	if len(appid) = 0 then response.end
	Dim upsetting
	Dim objPermission
	Set objPermission = new PermissionSetting
		With objPermission
			.memID = memID
			.appid = appid
			upsetting = .Upload
		End With
	Set objPermission = nothing
	if not isAdmin then
		if upsetting<>"" then 'see if the user is allowed to upload
			temparr = split(upsetting,"|")
			if isArray(temparr) then 'see if the user is allowed to upload again
				UpLoadSizeLimit = temparr(0)
				if ubound(temparr)=1 then 		'these two lines are requirements for user to upload
					uploadformat = temparr(1)	'both uploadformat and UpLoadSizeLimit have to have some values
				else
					uploadformat = ""
				end if
				if (UpLoadSizeLimit = "0" or len(UpLoadSizeLimit)=0) or (len(uploadformat)=0) then 'user not allowed to upload
					isUploadAllowed = false
				end if
			else
				isUploadAllowed = false 'temparr is empty
			end if
		else
			isUploadAllowed = false
		end if
	end if
	
	if (maxnumupload - existingUpfileCount <= 0) then 
		isUploadAllowed = false
		RightViolationMessage = replace(upfileMaxNumReached,"{num}",maxnumupload)
	end if
	
	maxnumupload  = maxnumupload - existingUpfileCount
End SELECT

'if not isUploadAllowed then
'	response.write (RightViolationMessage)
'	session.contents.remove(dbName&"UpLoadSizeLimit")
'	response.end
'end if

if isAdmin then
	UpLoadSizeLimit = "9999"
	uploadformat = uploadAllFormat
end if
' all user upload check is done at this point.
 %>
<html>
<head>
<title><%= Application(dbName&"forumtitle") %></title>
<%= NoScript() %>
<%= OutputCSS() %>
<script language="JavaScript" src ='js/trims.js'></script>
<script type="text/javascript">
<!--
function respondToUploader(form){
	var formFileLength
	var formFileExtension
	var formexp
	var canProceed = false
	
	for (var i=1; i<=<%= maxnumupload %>;i++){
	
		formFileLength = eval("form.File"+i+".value.trim().length")
		formFileExtension = eval("form.File"+i+".value")
		formexp = /.+(<%= replace("\."&uploadformat,"/","|\.") %>)[\"]*$/i
		
		if(formFileLength!=0 && formFileLength<5){
			alert("<%= profAllFieldReq %>");
			return false;
		}
		<% if not isAdmin then %>
		else if(! formexp.test(formFileExtension) && formFileLength!=0){
			alert(formFileExtension+"<%= " " & upFileTypeErr %>")
			return false;
		}
		<% end if %>
		else if (formFileLength!=0 && formFileLength>5) {
			canProceed = true
		}
	
	}

	if(canProceed){
		form.submitbutton.disabled = true;
		return true;
	}else{
		alert("<%= profAllFieldReq %>");
		return false;
	}
}
if (opener == null || opener.closed) {self.location.href="<%= forumdir %>"}
//-->
</script>
 </head>
<body <%= Application(dbName&"bodyoption") %>>
<table width="100%" border="0" cellspacing="0" cellpadding="0">
  <tr> 
	<td bgcolor="<%=tableborder%>"> 
	  <table width="100%" border="0" cellspacing="1" cellpadding="4">
		<tr> 
		  <th bgcolor="<%=tabletitle%>">
		  	<font class="subhead" color="<%=titlefontcolor%>">
			<%= upFileDesc %>
		  	</font></th>
		</tr>
	  </table>
	</td>
  </tr>
</table>
<br>
<% if isUploadAllowed then %>

<% session(dbName&"UpLoadSizeLimit") = UpLoadSizeLimit %>
<table width="100%" border="0" cellspacing="0" cellpadding="0">
<form method="POST" 
 action="uploadpro.asp?memori=<%= memori %>&deletefile=<%= deletefile %>&mode=<%= mode %>"
 enctype="multipart/form-data" onSubmit="return respondToUploader(this)">
  <tr> 
	<td bgcolor="<%=tableborder%>"> 
	  <table width="100%" border="0" cellspacing="1" cellpadding="4">
		<tr> 
		  <td <%=tableinside%>>
			  <%= upFileDesc %><br>
			  <% for i=1 to maxnumupload %>
			  <input type="file" name="File<%= i %>" size="25">
			  <% next %>
			  <input type="hidden" name="maxnumupload" value="<%= maxnumupload %>"><br><br>
			<% if mode="sig" then %>
				(<%= (Application(dbName&"leftframe")-5) %> X <%= (Application(dbName&"leftframe")-5) %>)
			<% elseif mode="prof" then %>
				(<%= (Application(dbName&"leftframe")-5)*2 %> X <%= (Application(dbName&"leftframe")-5)*2 %>)
			<% end if %>
				<%= forumMax & UpLoadSizeLimit %>KB; <br><%= uploadformat & " " & upFileTypeSupport%>			  
		  </td>
		</tr>
	  </table>
	</td>
  </tr>
  <tr>
    <td>
	  <hr size="1" noshade>
	</td>
  </tr>
  <tr>
      <td align="center"> 
		<input type="submit" name="submitbutton" value="<%= buttonSubmitValue %>" class="buttons">
		<input type="button" onclick="self.close(); opener.focus()" value="<%= buttonCloseWindowValue %>" class="buttons">
	  </td>
  </tr>
</form>
</table>
<% Else %>
<div align="center"><%= RightViolationMessage %><br><br>
	<a href="#" onclick="self.close(); opener.focus()"><%= javascriptCloseWindow %></a></div>
	<% session.contents.remove(dbName&"UpLoadSizeLimit") %>
<% End If %>
<pre>
</pre>
</body> 
</html>