<% 
session.timeout = Application(dbName&"sessiontimeout")
Dim strSession, guestViewPref, selfPage, queryString, clientIP, Server_Name
selfPage = Request.ServerVariables("PATH_INFO")
queryString = request.querystring

if session(dbName&"MemInfo")="" then
'''uncomment the following line when you install the forum on your production server. This increases accuracy and security of the forum.
	if _
	addTrailingSlash(lcase(HostType & Left(Request.ServerVariables("SERVER_NAME")&Request.ServerVariables("PATH_INFO"),InstrRev(Request.ServerVariables("SERVER_NAME")&Request.ServerVariables("PATH_INFO"),"/")))) <> _
	addTrailingSlash(lcase(forumdir)) then _
	response.redirect (addTrailingSlash(lcase(forumdir)))
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
	Dim browser:browser = CheckBrowserType()
	
	if request.cookies(dbName&"lastVisit")="" then
		memLastVisit = SQLNowDate()
		response.cookies(dbName&"lastVisit") =  FormatDateTime(SQLNowDate())
		response.cookies(dbName&"lastvisit").Expires = date + 1000
	end if
	
	if browser = "moz6" then guestViewPref = Application(dbName&"viewPref") else guestViewPref = 0
	
	session(dbName&"MemInfo")="-1"&chr(1)&"Guest"&chr(1)&browser&chr(1)&request.cookies(dbName&"lastvisit")&chr(1)&guestViewPref
	Session(dbName&"isThereNewPM") = 0
end if

Dim memID, memLogin, memBrowser, memLastVisit, arrMemberInfo, memViewPref, memBlockList
arrMemberInfo = split(session(dbName&"MemInfo"),chr(1))
call checkSessionIntegrity(arrMemberInfo)
memID=arrMemberInfo(0)
memLogin=arrMemberInfo(1)
memBrowser=arrMemberInfo(2)
memLastVisit=arrMemberInfo(3)
memViewPref=Cint(arrMemberInfo(4))
erase arrMemberInfo

if memID = "-1" then 'Auto Login
	if ipcheck() = "blocked" then
		response.write (replace(IPBlockedMessage,"%ip%", clientIP))
		session.contents.removeall 
		session.abandon
		response.end
	end if
	Dim autoLogin, autoPassword
	autoLogin = getLoginCookies()
    autoPassword = getPassCookies()
	if len(autoLogin)<>0 and len(autoPassword)<>0 then
		if LogOnToForumMD5 (autoLogin, autoPassword, false) then
			arrMemberInfo = split(session(dbName&"MemInfo"),chr(1))
			call checkSessionIntegrity(arrMemberInfo)
			memID=arrMemberInfo(0)
			memLogin=arrMemberInfo(1)
			memBrowser=arrMemberInfo(2)
			memLastVisit=arrMemberInfo(3)
			memViewPref=Cint(arrMemberInfo(4))
			erase arrMemberInfo	
		end if
	end if
end if

'########## new variable to speed up processing
Dim isGuest:isGuest = iff(memID="-1",true,false)
'##########

if not isGuest then	memBlockList = Request.Cookies(dbName&"blockLists")&""

Dim alladmin:alladmin = Application(dbName&"alladmin")
Dim allumanager:allumanager = Application(dbName&"allumanager")
Dim allfmanager:allfmanager = Application(dbName&"allfmanager")
Dim isAdmin:isAdmin = false
Dim isFMan:isFMan = false
Dim isUMan:isUMan = false
Dim isBMan:isBMan = false
isBMan = BoardManager(memID)
isUMan = UserManager(memID)
isFMan = ForumManager(memID)
if isBMan or isUMan or isFMan then isAdmin = true

if Application(dbName&"boarddown") = 1 and instr(selfpage,"/logpro.asp") = 0 and not isAdmin and instr(selfpage,"/login.asp") = 0 and instr(selfpage,"/boarddown.asp")=0 then _
	response.redirect ("boarddown.asp")


Dim proceedWithSessionTableCleanUp:proceedWithSessionTableCleanUp = false

if Application(dbName&"onlineTracking") = 1 then
	Call OnlineUserLog()
	Call OnlineUserCleanUp()
	
	Dim sessAppid, sessMid
	if instr(querystring,"=") then
		sessAppid = request.querystring("appid")
		sessMid = request.querystring("m")
	else
		Dim sessAppidStart,sessMidStart
		
		sessAppidStart = instr(queryString,"appid_")+6
		if sessAppidStart > 6 then
			sessAppid = mid(querystring,sessAppidStart,instr(sessAppidStart,queryString,"/")-sessAppidStart)
		end if
		
		sessMidStart = instr(queryString,"m_")+2
		if sessMidStart > 2 then
			sessMid = mid(querystring,sessMidStart,instr(sessMidStart,queryString,"/")-sessMidStart)
		end if
		
	end if
	Call InsertUpdateSession(session.sessionID, memID, memLogin, SQLNowDate(), selfPage, sessAppid&"", sessMid&"")
end if

%>

<script runat="server" language="VBScript">

sub OnlineUserLog()
	Dim strActiveUserList
	Dim intUserStart, intUserEnd
	Dim strUser
	Dim strDate
	
	strActiveUserList = Application(dbName&"pgd_userList")
	
	If Instr(1, strActiveUserList, Session.SessionID) > 0 Then
		intUserStart = Instr(1, strActiveUserList, Session.SessionID)
		intUserEnd = Instr(intUserStart, strActiveUserList, "|")
		strUser = Mid(strActiveUserList, intUserStart, intUserEnd - intUserStart)
		strActiveUserList = Replace(strActiveUserList, strUser, Session.SessionID & ":" & Now())
		Application.Lock
		Application(dbName&"pgd_userList") = strActiveUserList
		Application.UnLock
	Else
		Application.Lock
		Application(dbName&"pgd_activeUser") = CInt(Application(dbName&"pgd_activeUser")) + 1
		Application(dbName&"pgd_userList") = Application(dbName&"pgd_userList") & Session.SessionID & ":" & Now() & "|"
		Application.UnLock
	End If
end sub

sub OnlineUserCleanUp()
	Dim ix
	Dim intUsers
	Dim strActiveUserList
	Dim aActiveUsers
	Dim intActiveUserCleanupTime
	Dim intActiveUserTimeout
	
	intActiveUserCleanupTime = 1 'In minutes, how often should the ActiveUserList be cleaned up.
	intActiveUserTimeout = Application(dbName&"sessiontimeout") 'In minutes, how long before a User is considered Inactive and is deleted from ActiveUserList
	
	If Application(dbName&"pgd_userList") = "" Then Exit Sub
	
	If DateDiff("n", Application(dbName&"pgd_userLastClean"), Now()) < intActiveUserCleanupTime Then Exit Sub
	
	intUsers = 0
	strActiveUserList = Application(dbName&"pgd_userList")
	strActiveUserList = Left(strActiveUserList, Len(strActiveUserList) - 1)
	
	aActiveUsers = Split(strActiveUserList, "|")
	
	For ix = 0 To UBound(aActiveUsers)
	If DateDiff("n", Mid(aActiveUsers(ix), Instr(1, aActiveUsers(ix), ":") + 1), Now()) > intActiveUserTimeout Then
	    aActiveUsers(ix) = "DELETED"
	Else
	    intUsers = intUsers + 1
	End If 
	Next
	
	strActiveUserList = Join(aActiveUsers, "|") & "|"
	strActiveUserList = Replace(strActiveUserList, "DELETED|", "")
	
	Application.Lock
	Application(dbName&"pgd_userList") = strActiveUserList
	Application(dbName&"pgd_activeUser") = intUsers
	Application(dbName&"pgd_userLastClean") = Now()
	Application.UnLock
	proceedWithSessionTableCleanUp = true
end sub

Sub OnlineUserLogOut(SID)
	Dim strActiveUserList
	Dim intUserStart, intUserEnd
	Dim strUser
	strActiveUserList = Application(dbName&"pgd_userList")
	
	If Instr(1, strActiveUserList, SID) > 0 Then
		intUserStart = Instr(1, strActiveUserList, SID)
		intUserEnd = Instr(intUserStart, strActiveUserList, "|")
		strUser = Mid(strActiveUserList, intUserStart, intUserEnd - intUserStart)
		strActiveUserList = Replace(strActiveUserList, strUser, "DELETED")	
		strActiveUserList = Replace(strActiveUserList, "DELETED|", "")
		Application.Lock
		Application(dbName&"pgd_userList") = strActiveUserList
		Application(dbName&"pgd_activeUser") = Application(dbName&"pgd_activeUser") - 1
		Application.UnLock			
	End If
End sub

sub InsertUpdateSession(sessionID, mem, login, lastActivity, whereAbout, appidQS, mQS)
	if isGuest then exit sub
	if len(appidQS) = 0 or not isNumeric (appidQS) then appidQS = -1
	if len(mQS) = 0 or not isNumeric (mQS) then mQS = -1
	Dim objCom
	Dim isThereNewPM
	set objCom = server.createobject("adodb.command")
    	With objCom
    		.activeConnection = datastore 
    		.commandText = dbOwnerPrefix&"spInsertUpdateSession"
    		.commandType = adCmdStoredProc
			.Parameters.Append .Createparameter("@sessionID", adVarChar, adParamInput, 50, sessionID)
			.Parameters.Append .Createparameter("@mem", adInteger, adParamInput, 0, mem)
			.Parameters.Append .Createparameter("@login", adVarChar, adParamInput, 50, login)
			.Parameters.Append .Createparameter("@whereAbout", adVarChar, adParamInput, 100, left(whereAbout,100))
			.Parameters.Append .Createparameter("@appid", adInteger, adParamInput, 0, Clng(appidQS))
			.Parameters.Append .Createparameter("@m", adInteger, adParamInput, 0, Clng(mQS))
			.Parameters.Append .Createparameter("@isThereNewPM", adInteger, adParamOutput, 0 )
			.Parameters.Append .Createparameter("@allowHide", adUnsignedTinyInt, adParamInput, 0,Application(dbName&"allowHide"))

    		.execute , , adExecuteNoRecords
			isThereNewPM = .Parameters("@isThereNewPM")
    	End With
    set objCom = nothing
	if isThereNewPM>0 then Session(dbName&"isThereNewPM") = isThereNewPM
end sub

function Administrator(userID)
	Administrator = false
	if BoardManager(userID) then Administrator = true
	if ForumManager(userID) then Administrator = true
	if UserManager(userID) then Administrator = true
end function

function BoardManager(userID)
	BoardManager = false
	if Instr(1, "," & alladmin & ",", "," & userID & ",", 0) > 0 then BoardManager = true
end function

function ForumManager(userID)
	ForumManager = false
	if Instr(1, "," & allfmanager & ",", "," & userID & ",", 0) > 0 then ForumManager = true
end function

function UserManager(userID)
	UserManager = false
	if Instr(1, "," & allumanager & ",", "," & userID & ",", 0) > 0 then UserManager = true
end function

sub checkSessionIntegrity(arrSession)
	if ubound (arrSession) <> 4 then
		session(dbName&"MemInfo") = ""
		response.redirect ("default.asp")
		response.end
	end if
end sub

function IPcheck()
	dim ipblocked, arrBanIP, objExpIP
	
	clientIP = request.ServerVariables("REMOTE_ADDR")
	
	ipblocked = CheckDelimitedFormat(""&Application(dbName&"bannedIP"),"|")
	
	if len(ipblocked)=0 then
		IPcheck = "safe"
		exit function
	end if
	
	ipblocked = iff(len(ipblocked)=0,"",ipblocked)
	
	ipblocked = replace(ipblocked,".","\.")
	ipblocked = replace(ipblocked,"**","\d{2}")
	ipblocked = replace(ipblocked,"*","\d{1,3}")
	ipblocked = "^("&ipblocked&")"
	
	'response.write(ipblocked)'
	
	Set objExpIP = New regexp
		With objExpIP
		
		dim i, ifInStr, newIP
			.pattern = ipblocked
			.global = false
			.ignorecase = false
			if .test(clientIP) then 
				IPcheck ="blocked" 
			else 
				IPcheck = "safe"
			end if
		
		End with
	set objExpIP = nothing
end function

function LogOnToForumMD5(login,password, fromLoginPage)
	if ipcheck() = "blocked" then
		response.write (replace(IPBlockedMessage,"%ip%", clientIP))
		session.contents.removeall 
		session.abandon
		response.end
	end if
	
	Dim status, viewpref
	Dim objRS, mem,userpass, isMd5, objCon, regStatus, banned
	Dim saltedMD5Pass
	
	status = 0
	
	set objRS = server.createobject("adodb.recordset")
   		with objRS
   			.open "SELECT userpass,viewpref,mem,isMd5,login, regStatus, banned FROM pgd_members WHERE login='"&login&"'", datastore, , , adCmdText
	   			If not (.EOF or .BOF) then
	   				userpass = .fields(0)
					viewpref = .fields(1)
					mem = .fields(2)
					isMd5 = .fields(3)
					login = .fields(4)
					regStatus = .fields(5)
					banned = .fields(6)
					
					if regStatus<>0 then
						status = -1
						if fromLoginPage then loginFailureReason = iff(regStatus=1,4,5)
					end if
					
					if banned<>0 then
						status = -1
						if fromLoginPage then loginFailureReason = 1
					end if
				else
					status = -1
					if fromLoginPage then loginFailureReason = 2
	   			End if
   			.close
   		end with
   	set objRS=nothing
	
	if status <> -1 then
		
		if fromLoginPage then saltedMD5Pass = hex_md5(login&password) else saltedMD5Pass = password
		
		if isMd5 = 1 then
			if saltedMD5Pass <> userpass then 
				status = -1
				if fromLoginPage then loginFailureReason = 3
			end if
		else
			if password = userpass then
				saltedMD5Pass = hex_md5(login&password)
				SET objCon = server.createObject("ADODB.connection")
	               	with objCon
	               		.open datastore
	               			.execute "update pgd_members Set userpass='"&saltedMD5Pass&"', isMd5=1 WHERE login='"&login&"'", , adExecuteNoRecords + adCmdtext 
	               		.close
	               	end with
               	Set objCon = nothing
			else
				status = -1
				if fromLoginPage then loginFailureReason = 3
			end if
		end if
	end if

	If status = 0 then
		
		SET objCon = server.createObject("ADODB.connection")
    	with objCon
    		.open datastore
    			.execute "UPDATE pgd_members SET ip = '"&Request.ServerVariables("REMOTE_ADDR")&"', lastLogin = GetDate() WHERE Mem = "&mem, , adExecuteNoRecords + adCmdtext 
    		.close
    	end with
    	Set objCon = nothing
		
		if (membrowser <> "moz6" and viewpref=1) then viewpref = 0
		session(dbName&"MemInfo") = mem&chr(1)&login&chr(1)&memBrowser&chr(1)&memLastVisit&chr(1)&viewpref
		call GetBlockedList(mem)
		
		if fromLoginPage then password = saltedMD5Pass	else call setAutoCookies (login,saltedMD5Pass)
				
		LogOnToForumMD5 = true
		
	ElseIf status = -1 then
		
		call delAutoCookies ()
		LogOnToForumMD5 = false
		
	End If
	
end function

Function rndPasswd(intPassLength)
     Dim strPassword:strPassword = ""
     Do Until Len(strPassword) = intPassLength
           strPassword = strPassword & Chr(rndnumber(65,90))
     Loop
     rndPasswd = strPassword
End Function

'The encryption code are based on Lewis Moten's RC4 code (http://www.lewismoten.com)

Function RC4(ByRef pStrMessage, ByRef pStrKey)

	Dim lBytAsciiAry(255)
	Dim lBytKeyAry(255)
	Dim lLngIndex
	Dim lBytJump
	Dim lBytTemp
	Dim lBytY
	Dim lLngT
	Dim lLngX
	Dim lLngKeyLength
	Dim fStr
	Dim OriCodePage
	
	If Len(pStrKey) = 0 Then Exit Function
	If Len(pStrMessage) = 0 Then Exit Function

	OriCodePage = session.codepage
	session.codepage=1252
	
	lLngKeyLength = Len(pStrKey)
	For lLngIndex = 0 To 255
	    lBytKeyAry(lLngIndex) = Asc(Mid(pStrKey, ((lLngIndex) Mod (lLngKeyLength)) + 1, 1))
	Next

	For lLngIndex = 0 To 255
	    lBytAsciiAry(lLngIndex) = lLngIndex
	Next

	lBytJump = 0
	For lLngIndex = 0 To 255

	    lBytJump = (lBytJump + lBytAsciiAry(lLngIndex) + lBytKeyAry(lLngIndex)) Mod 256
	    
	    lBytTemp				= lBytAsciiAry(lLngIndex)
	    lBytAsciiAry(lLngIndex)	= lBytAsciiAry(lBytJump)
	    lBytAsciiAry(lBytJump)	= lBytTemp
	    
	Next

	lLngIndex = 0
	lBytJump = 0
	Set fStr = New StringBuilder
	For lLngX = 1 To Len(pStrMessage)
	    lLngIndex = (lLngIndex + 1) Mod 256 
	    lBytJump = (lBytJump + lBytAsciiAry(lLngIndex)) Mod 256 
	    
	    lLngT = (lBytAsciiAry(lLngIndex) + lBytAsciiAry(lBytJump)) Mod 256
	    
	    lBytTemp				= lBytAsciiAry(lLngIndex)
	    lBytAsciiAry(lLngIndex)	= lBytAsciiAry(lBytJump)
	    lBytAsciiAry(lBytJump)	= lBytTemp

	    lBytY = lBytAsciiAry(lLngT)
	
	    fStr.append(Chr(Asc(Mid(pStrMessage, lLngX, 1)) Xor lBytY))
	Next
	RC4 = fStr.Value
	set fStr = nothing
	session.codepage = OriCodePage
End Function

function StringToHex(ByRef pstrString)
	Dim llngIndex
	Dim llngMaxIndex
	Dim lstrHex
	Dim OriCodePage
	
	OriCodePage = session.codepage
	session.codepage=1252
		
	llngMaxIndex = Len(pstrString)
	Set lstrHex = New StringBuilder
	For llngIndex = 1 To llngMaxIndex
		lstrHex.append (Right("0" & Hex(Asc(Mid(pstrString, llngIndex, 1))), 2))
	Next
	StringToHex = lstrHex.value
	set lstrHex = nothing
	session.codepage = OriCodePage
End function

function HexToString(ByRef pstrHex)
	Dim llngIndex
	Dim llngMaxIndex
	Dim lstrString
	Dim OriCodePage
	
	OriCodePage = session.codepage
	session.codepage=1252
		
	llngMaxIndex = Len(pstrHex)
	Set lstrString = new StringBuilder
	For llngIndex = 1 To llngMaxIndex Step 2
		lstrString.append (Chr("&h" & Mid(pstrHex, llngIndex, 2)))
	Next
	HexToString = lstrString.value
	set lstrString = nothing
	session.codepage = OriCodePage
End function

Sub GetBlockedList(memID)
	Dim objRS, blockedListcookie
	set objRS = server.createobject("adodb.recordset")
   		with objRS
   			.CacheSize = 150
   			.open dbOwnerPrefix&"spFindBlocked ("&memID&")", datastore, , , adcmdStoredProc ''adCmdText
   			If not (.EOF or .BOF) then
   				blockedListcookie = .getString(,,"",",","")
			else
				blockedListCookie = ""
   			End if
   			.close
   		end with
   	set objRS=nothing
	Response.Cookies(dbName&"blockLists") = blockedListcookie
	Response.Cookies(dbName&"blockLists").Expires = date + 1
End Sub

sub setAutoCookies (login,pass)
	response.cookies(dbName&"ASPplayground_forum")("Login") = login
	response.cookies(dbName&"ASPplayground_forum")("Password") = StringToHex(RC4(pass, strRC4Password))
	response.Cookies(dbName&"loguser") = login
	response.cookies(dbName&"logpass") = pass
	response.Cookies(dbName&"loguser").path = "/"
	response.Cookies(dbName&"logpass").path = "/"
	if len(Application(dbName&"cookieDomain")&"") <> 0 then response.cookies(dbName&"ASPplayground_forum").domain = Application(dbName&"cookieDomain")
	if len(Application(dbName&"cookiePath")&"") <> 0 then response.cookies(dbName&"ASPplayground_forum").path = Application(dbName&"cookiePath")
	response.Cookies(dbName&"logpass").Expires = date + 30
	response.Cookies(dbName&"loguser").Expires = date + 30
	response.cookies(dbName&"ASPplayground_forum").Expires = date + 30
end sub

sub delAutoCookies ()
	if len(Application(dbName&"cookieDomain")&"") <> 0 then response.cookies(dbName&"ASPplayground_forum").domain = Application(dbName&"cookieDomain")
	if len(Application(dbName&"cookiePath")&"") <> 0 then response.cookies(dbName&"ASPplayground_forum").path = Application(dbName&"cookiePath")
	response.Cookies(dbName&"logpass").Expires = date - 1000
	response.Cookies(dbName&"loguser").Expires = date - 1000
	response.cookies(dbName&"ASPplayground_forum").Expires = date - 1000
end sub

function getLoginCookies()
	getLoginCookies = request.cookies(dbName&"ASPplayground_forum")("Login")&""
end function

function getPassCookies()
	getPassCookies = RC4(HexToString(request.cookies(dbName&"ASPplayground_forum")("Password")&""),strRC4Password)&""
end function

function CheckBrowserType()
	Dim str
	Dim browserExp
	str = request.servervariables("http_user_agent")
	Set browserExp = New RegExp
	browserExp.ignorecase = true
	browserExp.global = true
	
	browserExp.pattern = "\bwindows\b"
	if not browserExp.test(str) then
		CheckBrowserType = "moz4"
		exit function
	end if
	
	browserExp.pattern = "opera.[6-7]"
	if browserExp.test(str) then 
		CheckBrowserType = "moz5"
		exit function
	else
		browserExp.pattern = "Gecko"
		if browserExp.test(str) then
			CheckBrowserType = "moz5"
			exit function
		else
			browserExp.pattern = "MSIE\s[5-6]"
			if browserExp.test(str) then
				CheckBrowserType = "moz6"
			else
				CheckBrowserType = "moz4"
			end if
		end if
	end if
end function
</script>
<script runat="server" language="jscript">
/*
 * A JavaScript implementation of the RSA Data Security, Inc. MD5 Message
 * Digest Algorithm, as defined in RFC 1321.
 * Version 2.1 Copyright (C) Paul Johnston 1999 - 2002.
 * Other contributors: Greg Holt, Andrew Kepert, Ydnar, Lostinet
 * Distributed under the BSD License
 * See http://pajhome.org.uk/crypt/md5 for more info.
 */

var chrsz   = 8;  /* bits per input character. 8 - ASCII; 16 - Unicode      */

function hex_md5(s){ return binl2hex(core_md5(str2binl(s), s.length * chrsz));}

function core_md5(x, len)
{
  /* append padding */
  x[len >> 5] |= 0x80 << ((len) % 32);
  x[(((len + 64) >>> 9) << 4) + 14] = len;
  
  var a =  1732584193;
  var b = -271733879;
  var c = -1732584194;
  var d =  271733878;

  for(var i = 0; i < x.length; i += 16)
  {
    var olda = a;
    var oldb = b;
    var oldc = c;
    var oldd = d;
 
    a = md5_ff(a, b, c, d, x[i+ 0], 7 , -680876936);
    d = md5_ff(d, a, b, c, x[i+ 1], 12, -389564586);
    c = md5_ff(c, d, a, b, x[i+ 2], 17,  606105819);
    b = md5_ff(b, c, d, a, x[i+ 3], 22, -1044525330);
    a = md5_ff(a, b, c, d, x[i+ 4], 7 , -176418897);
    d = md5_ff(d, a, b, c, x[i+ 5], 12,  1200080426);
    c = md5_ff(c, d, a, b, x[i+ 6], 17, -1473231341);
    b = md5_ff(b, c, d, a, x[i+ 7], 22, -45705983);
    a = md5_ff(a, b, c, d, x[i+ 8], 7 ,  1770035416);
    d = md5_ff(d, a, b, c, x[i+ 9], 12, -1958414417);
    c = md5_ff(c, d, a, b, x[i+10], 17, -42063);
    b = md5_ff(b, c, d, a, x[i+11], 22, -1990404162);
    a = md5_ff(a, b, c, d, x[i+12], 7 ,  1804603682);
    d = md5_ff(d, a, b, c, x[i+13], 12, -40341101);
    c = md5_ff(c, d, a, b, x[i+14], 17, -1502002290);
    b = md5_ff(b, c, d, a, x[i+15], 22,  1236535329);

    a = md5_gg(a, b, c, d, x[i+ 1], 5 , -165796510);
    d = md5_gg(d, a, b, c, x[i+ 6], 9 , -1069501632);
    c = md5_gg(c, d, a, b, x[i+11], 14,  643717713);
    b = md5_gg(b, c, d, a, x[i+ 0], 20, -373897302);
    a = md5_gg(a, b, c, d, x[i+ 5], 5 , -701558691);
    d = md5_gg(d, a, b, c, x[i+10], 9 ,  38016083);
    c = md5_gg(c, d, a, b, x[i+15], 14, -660478335);
    b = md5_gg(b, c, d, a, x[i+ 4], 20, -405537848);
    a = md5_gg(a, b, c, d, x[i+ 9], 5 ,  568446438);
    d = md5_gg(d, a, b, c, x[i+14], 9 , -1019803690);
    c = md5_gg(c, d, a, b, x[i+ 3], 14, -187363961);
    b = md5_gg(b, c, d, a, x[i+ 8], 20,  1163531501);
    a = md5_gg(a, b, c, d, x[i+13], 5 , -1444681467);
    d = md5_gg(d, a, b, c, x[i+ 2], 9 , -51403784);
    c = md5_gg(c, d, a, b, x[i+ 7], 14,  1735328473);
    b = md5_gg(b, c, d, a, x[i+12], 20, -1926607734);

    a = md5_hh(a, b, c, d, x[i+ 5], 4 , -378558);
    d = md5_hh(d, a, b, c, x[i+ 8], 11, -2022574463);
    c = md5_hh(c, d, a, b, x[i+11], 16,  1839030562);
    b = md5_hh(b, c, d, a, x[i+14], 23, -35309556);
    a = md5_hh(a, b, c, d, x[i+ 1], 4 , -1530992060);
    d = md5_hh(d, a, b, c, x[i+ 4], 11,  1272893353);
    c = md5_hh(c, d, a, b, x[i+ 7], 16, -155497632);
    b = md5_hh(b, c, d, a, x[i+10], 23, -1094730640);
    a = md5_hh(a, b, c, d, x[i+13], 4 ,  681279174);
    d = md5_hh(d, a, b, c, x[i+ 0], 11, -358537222);
    c = md5_hh(c, d, a, b, x[i+ 3], 16, -722521979);
    b = md5_hh(b, c, d, a, x[i+ 6], 23,  76029189);
    a = md5_hh(a, b, c, d, x[i+ 9], 4 , -640364487);
    d = md5_hh(d, a, b, c, x[i+12], 11, -421815835);
    c = md5_hh(c, d, a, b, x[i+15], 16,  530742520);
    b = md5_hh(b, c, d, a, x[i+ 2], 23, -995338651);

    a = md5_ii(a, b, c, d, x[i+ 0], 6 , -198630844);
    d = md5_ii(d, a, b, c, x[i+ 7], 10,  1126891415);
    c = md5_ii(c, d, a, b, x[i+14], 15, -1416354905);
    b = md5_ii(b, c, d, a, x[i+ 5], 21, -57434055);
    a = md5_ii(a, b, c, d, x[i+12], 6 ,  1700485571);
    d = md5_ii(d, a, b, c, x[i+ 3], 10, -1894986606);
    c = md5_ii(c, d, a, b, x[i+10], 15, -1051523);
    b = md5_ii(b, c, d, a, x[i+ 1], 21, -2054922799);
    a = md5_ii(a, b, c, d, x[i+ 8], 6 ,  1873313359);
    d = md5_ii(d, a, b, c, x[i+15], 10, -30611744);
    c = md5_ii(c, d, a, b, x[i+ 6], 15, -1560198380);
    b = md5_ii(b, c, d, a, x[i+13], 21,  1309151649);
    a = md5_ii(a, b, c, d, x[i+ 4], 6 , -145523070);
    d = md5_ii(d, a, b, c, x[i+11], 10, -1120210379);
    c = md5_ii(c, d, a, b, x[i+ 2], 15,  718787259);
    b = md5_ii(b, c, d, a, x[i+ 9], 21, -343485551);

    a = safe_add(a, olda);
    b = safe_add(b, oldb);
    c = safe_add(c, oldc);
    d = safe_add(d, oldd);
  }
  return Array(a, b, c, d);
  
}

function md5_cmn(q, a, b, x, s, t)
{
  return safe_add(bit_rol(safe_add(safe_add(a, q), safe_add(x, t)), s),b);
}
function md5_ff(a, b, c, d, x, s, t)
{
  return md5_cmn((b & c) | ((~b) & d), a, b, x, s, t);
}
function md5_gg(a, b, c, d, x, s, t)
{
  return md5_cmn((b & d) | (c & (~d)), a, b, x, s, t);
}
function md5_hh(a, b, c, d, x, s, t)
{
  return md5_cmn(b ^ c ^ d, a, b, x, s, t);
}
function md5_ii(a, b, c, d, x, s, t)
{
  return md5_cmn(c ^ (b | (~d)), a, b, x, s, t);
}

function safe_add(x, y)
{
  var lsw = (x & 0xFFFF) + (y & 0xFFFF);
  var msw = (x >> 16) + (y >> 16) + (lsw >> 16);
  return (msw << 16) | (lsw & 0xFFFF);
}

function bit_rol(num, cnt)
{
  return (num << cnt) | (num >>> (32 - cnt));
}

function str2binl(str)
{
  var bin = Array();
  var mask = (1 << chrsz) - 1;
  for(var i = 0; i < str.length * chrsz; i += chrsz)
    bin[i>>5] |= (str.charCodeAt(i / chrsz) & mask) << (i%32);
  return bin;
}

function binl2hex(binarray)
{
  var hex_tab = "0123456789ABCDEF";
  var str = "";
  for(var i = 0; i < binarray.length * 4; i++)
  {
    str += hex_tab.charAt((binarray[i>>2] >> ((i%4)*8+4)) & 0xF) +
           hex_tab.charAt((binarray[i>>2] >> ((i%4)*8  )) & 0xF);
  }
  return str;
}

</script>