<!--#include file="masterinclude.asp"-->
<!--#include file="language.asp"-->
<!--#include file="session.asp"-->
<!--#include file="js/mailroutine.asp"-->
<!--#include file="js/io.asp"-->
<!--#include file="js/right_functions.asp"-->
<%

Dim memEdited, impersonate

memEdited = memID
impersonate = len(session(dbName&"Impersonate")&"")

if not fromThisDomain("editprofile.asp") then
	response.redirect (forumdir&"first.asp?error=referer")
	response.end
end if

if request.form("jsenabled")="false" then 
	response.redirect (forumdir&"first.asp")
	response.end
end if

Dim lname, Email, cookies, objCom, fname, SQL, objRS, viewpref, sigpicture, emailview,password
Dim signature, homepage , apply, ok
Dim location, ICQ, Yahoo, AOL, interests, occupation, saysomething, avatar, avatarOrSigpicture, alwaysSig, acceptShortMsg,PMEmailNotify, PMPopUp, hidden
Dim profilePic, profilePicURL, URLorProfPic, profUseSigPic, emailori, regType,MSNMsger
Dim bDay, bMonth, bYear, hideProfile, hideyear

fname = request.form("fname")
lname = request.form("lname")
Email = trim(request.form("email"))
emailori = request.form("emailori")
homepage = request.form("homepage")
signature = request.form("signature")
viewpref = request.form("viewpref")
cookies = request.form("cookies")
sigpicture = request.form("upfile")
emailview = request.form("emailview")
location = request.form("location")
ICQ = request.form("ICQ")
Yahoo = request.form("Yahoo")
AOL = request.form("AOL")
interests = request.form("interests")
occupation = request.form("occupation")
saysomething = request.form("saysomething")
apply = request.form("apply")
ok = request.form("ok")
avatar = request.form("avatar")
avatarOrSigpicture = request.form("avatarOrSigpicture")
alwaysSig = request.form("alwaysSig")
acceptShortMsg = request.form("acceptShortMsg")
PMEmailNotify = request.form("PMEmailNotify")
PMPopUp = request.form("PMPopUp")
hidden = request.form("hidden")
profilePic = request.form("upfile1")
profilePicURL = request.form("profilePicURL")
URLorProfPic = request.form("URLorProfPic")
profUseSigPic = request.form("profUseSigPic")
MSNMsger = request.form("MSNMsger")
bDay = request.form("bDay")
bMonth = request.form("bMonth")
bYear = request.form("bYear")
hideProfile = request.form("hideProfile")
hideyear = request.form("hideyear")

Dim NoSmile, NoImage, NoAvatar,PMAlwaysSave
NoSmile = request.form("NoSmile")
NoImage = request.form("NoImage")
NoAvatar = request.form("NoAvatar")		
PMAlwaysSave = request.form("PMAlwaysSave")
regType=Application(dbName&"regType")

if avatarOrSigpicture = "" then
	if Application(dbName&"allowAvatar")=0 then avatarOrSigpicture = 1 else avatarOrSigpicture = 0
end if

Dim confirmationResendDueToEmailChange:confirmationResendDueToEmailChange = false

if lcase(trim(Email))<>lcase(trim(emailori)) and (regType = 1 or regType = 2) then confirmationResendDueToEmailChange = true

signature= SQLin(signature)

saysomething= SQLin(saysomething)

alwaysSig = CheckedOrNot(alwaysSig)

hideyear = CheckedOrNot(hideyear)

NoSmile = CheckedOrNot(NoSmile)

NoImage = CheckedOrNot(NoImage)

NoAvatar = CheckedOrNot(NoAvatar)

PMAlwaysSave = CheckedOrNot(PMAlwaysSave)

acceptShortMsg = CheckedOrNot(acceptShortMsg)

emailview = CheckedOrNot(emailview)

hideProfile = CheckedOrNot(hideProfile)

PMPopUp = CheckedOrNot(PMPopUp)

PMEmailNotify = CheckedOrNot(PMEmailNotify)

hidden = CheckedOrNot(hidden)

profUseSigPic = CheckedOrNot(profUseSigPic)

if URLorProfPic = "" then URLorProfPic = 0

if replace(homepage,"http://","") = "" then homepage=""

if not isDate(bYear&"-"&LeadingZero(bMonth)&"-"&LeadingZero(bDay)) then
	bYear = 0
	bDay = 0
	bMonth = 0
end if

viewpref = iff(len(viewpref)=0,0,viewpref)

'===================================================
set objCom = server.createobject("adodb.command")
	With objCom
		.activeConnection = datastore 
		.commandText = dbOwnerPrefix&"spEditProfile"
		.commandType = adCmdStoredProc
		.Parameters.Append .Createparameter("@RETURN_VALUE", adInteger, adParamReturnValue, 0)
		.Parameters.Append .Createparameter("@nv_setp_First", adVarChar, adParamInput, 50, left(""&fname,50))
		.Parameters.Append .Createparameter("@nv_setp_Last", adVarChar, adParamInput, 50, left(""&lname,50))
		.Parameters.Append .Createparameter("@nv_setp_Email", adVarChar, adParamInput, 50, left(""&Email,50))
		.Parameters.Append .Createparameter("@nv_setp_homepage", adVarChar, adParamInput, 50, left(""&homepage,50))
		.Parameters.Append .Createparameter("@nv_setp_signature", adVarChar, adParamInput, 255, left(""&signature,255))
		.Parameters.Append .Createparameter("@nv_setp_Password", adVarChar, adParamInput, 50, "")
		.Parameters.Append .Createparameter("@int_setp_Mem", adInteger, adParamInput, 0, memEdited)
		.Parameters.Append .Createparameter("@nv_setp_viewpref", adInteger, adParamInput, 0, viewpref)
		.Parameters.Append .Createparameter("@nv_setp_sigpicture", adVarChar, adParamInput, 50, left(""&sigpicture,50))
		.Parameters.Append .Createparameter("@nv_setp_emailview", adUnsignedTinyInt, adParamInput, 0, emailview)
		.Parameters.Append .Createparameter("@location", adVarChar, adParamInput, 50, left(""&location,50))
		.Parameters.Append .Createparameter("@ICQ", adVarChar, adParamInput, 50, left(""&ICQ,50))
		.Parameters.Append .Createparameter("@Yahoo", adVarChar, adParamInput, 50, left(""&Yahoo,50))
		.Parameters.Append .Createparameter("@AOL", adVarChar, adParamInput, 50, left(""&AOL,50))
		.Parameters.Append .Createparameter("@interests", adVarChar, adParamInput, 50, left(""&interests,50))
		.Parameters.Append .Createparameter("@occupation", adVarChar, adParamInput, 50, left(""&occupation,50))
		.Parameters.Append .Createparameter("@saysomething", adVarChar, adParamInput, 255, left(""&saysomething,255))
		.Parameters.Append .Createparameter("@avatar", adVarChar, adParamInput, 100, left(""&avatar,100))
		.Parameters.Append .Createparameter("@avatarOrSigpicture", adUnsignedTinyInt, adParamInput, 0, avatarOrSigpicture)
		.Parameters.Append .Createparameter("@alwaysSig", adUnsignedTinyInt, adParamInput, 0, alwaysSig)
		.Parameters.Append .Createparameter("@acceptShortMsg", adUnsignedTinyInt, adParamInput, 0, acceptShortMsg)
		.Parameters.Append .Createparameter("@PMEmailNotify", adUnsignedTinyInt, adParamInput, 0, PMEmailNotify)
		.Parameters.Append .Createparameter("@PMPopUp", adUnsignedTinyInt, adParamInput, 0, PMPopUp)
		.Parameters.Append .Createparameter("@hidden", adUnsignedTinyInt, adParamInput, 0, hidden)
		.Parameters.Append .Createparameter("@profilePic", adVarChar, adParamInput, 50, left(""&profilePic,50))
		.Parameters.Append .Createparameter("@profilePicURL", adVarChar, adParamInput, 150, left(""&profilePicURL,150))
		.Parameters.Append .Createparameter("@URLorProfPic", adUnsignedTinyInt, adParamInput, 0, URLorProfPic)
		.Parameters.Append .Createparameter("@profUseSigPic", adUnsignedTinyInt, adParamInput, 0, profUseSigPic)
		.Parameters.Append .Createparameter("@MSNMsger", adVarChar, adParamInput, 50, left(""&MSNMsger,100))
		.Parameters.Append .Createparameter("@bDay", adUnsignedTinyInt, adParamInput, 0, bDay)
		.Parameters.Append .Createparameter("@bMonth", adUnsignedTinyInt, adParamInput, 0, bMonth)
		.Parameters.Append .Createparameter("@bYear", adInteger, adParamInput, 0, bYear)
		.Parameters.Append .Createparameter("@hideProfile", adUnsignedTinyInt, adParamInput, 0, hideProfile)
		.Parameters.Append .Createparameter("@hideyear", adUnsignedTinyInt, adParamInput, 0, hideyear)
		.Parameters.Append .Createparameter("@output_userpass", adVarChar, adParamOutput, 50)
		.execute , , adExecuteNoRecords
		Dim returned
		returned = .parameters("@RETURN_VALUE")
		password = .parameters("@output_userpass")
	End With
set objCom = nothing

if returned = -1 then
	response.redirect ("editprofile.asp?error=email")
	response.end
end if

'*** new code for additional fields
Dim fldCount:fldCount = cInt(request.form("fldCount"))

if fldCount>0 then
	Dim formClass
	
	Dim arrFields(), arrValues()
	
	Redim arrFields(fldCount) : Redim arrValues(fldCount)
	arrFields(0)="Mem":arrValues(0)=memEdited
	
	Dim iFld:iFld = 1
	
	for each formClass in request.form
		if left(formClass,4)= "fld_" or left(formClass,4)= "lfld" then 
			arrFields(iFld) = formClass
			arrValues(iFld) = iff(len(""&request.form(formClass)), trim(request.form(formClass)&""),"")
			arrFields(iFld+1) = "h_"&formClass
			arrValues(iFld+1) = iff(len(""&request.form("h_"&formClass)), request.form("h_"&formClass),"0")
			iFld = iFld + 2
		end if
	next
	
'	for iFld = 0 to ubound(arrFields)
'		response.write arrFields(iFld)&":"&arrValues(iFld)&"<br>"
'	next
	
'	response.end
	
	set objRS = server.createobject("adodb.recordset")
  		with objRS
			.open "SELECT * FROM pgd_regFields WHERE mem="&memEdited, datastore, adOpenDynamic, adLockOptimistic, adCmdText
			if not (.EOF or .BOF) then
			.update arrFields, arrValues
			else
  			.AddNew arrFields, arrValues
			end if
  			.close
  		end with
  	set objRS=nothing
end if
'*** new code for additional fields

'====================================================

if cookies="on" and impersonate=0 then
	call setAutoCookies(memLogin, password)
elseif cookies<>"on" and impersonate=0 then
	call delAutoCookies ()
end if

if impersonate=0 then
	response.cookies(dbName&"ASPplayground_forum_Speed")("NoSmile") = NoSmile
	response.cookies(dbName&"ASPplayground_forum_Speed")("NoImage") = NoImage
	response.cookies(dbName&"ASPplayground_forum_Speed")("NoAvatar") = NoAvatar		
	response.cookies(dbName&"ASPplayground_forum_Speed").Expires = date + 1000
	response.cookies(dbName&"PMAlwaysSave") = PMAlwaysSave
	response.cookies(dbName&"PMAlwaysSave").Expires = date + 1000
	response.cookies(dbName&"memTimeOffset") = request.form("memTimeOffset")
	response.cookies(dbName&"memTimeOffset").Expires = date + 1000
	response.cookies(dbName&"lanProfile") = request.form("lanprofileselect")
	response.cookies(dbName&"lanProfile").Expires = date + 1000
end if

session(dbName&"meminfo") = memID&chr(1)&memLogin&chr(1)&memBrowser&chr(1)&memLastVisit&chr(1)&viewpref

if confirmationResendDueToEmailChange then
	Call confirmResend(memID,regType)
	if regType = 1 then
		response.redirect ("redirect.asp?do=reset")
	else
		response.redirect ("redirect.asp?do=reapprove")
	end if
else
	if apply = buttonApplyValue then
		response.redirect("editProfile.asp")
	else
		response.redirect (forumdir)
	end if
end if
 %>